; This is designed to be serial-line downloaded to cdcode.
;
; Our memory map:
;
;	[8c000000,8c010000)	Stack (r15 set by cdcode)
;	[8c010000,8c01????)	cdcode
;	[8c020000,8c030000)	our data segment
;	[8c030000,8c03????)	our text segment

	.include "regs.s"

	.include "maple-bits.s"

. = 0x8c020000
	.align	32
cmds:
	.long	[0 << XDESC_PORTSHIFT] | [1 << XDESC_LENSHIFT]
	.long	iresp & DMA_ADDRMASK
	MapleFrame	CMD_GETCOND, 0, ADDR_MAIN, 0, 0, 1
	.long	@BSL[FUNC_CONTROLLER]
	.long	XDESC_LAST | [0 << XDESC_PORTSHIFT] | [[[2f-1f]/4] << XDESC_LENSHIFT]
	.long	oresp & DMA_ADDRMASK
	MapleFrame	CMD_BLOCKWRITE, 0, ADDR_SUB1, 0, 0, [2f-1f]/4
1:	.long	@BSL[FUNC_LCD]
	.long	0
ocopy:
	.space	192
2:
	.align	32
iresp:
	.space	1024
oresp:
	.space	1024
	.align	4
curistate:
	.space	8
previstate:
	.space	8
obuf:
	.space	192

. = 0x8c030000
; The only things startup.s sets up that cdcode hasn't already done for
;  us are (1) fpscr and (2) clearing bss.  We don't have bss because we
;  aren't linked by a conventional linker, and we don't use floating
;  point so we don't care about fpscr.  So we have nothing to do here.
;  Just dive straight into the code.
	bsr	init_hw
	 nop
1:	bsr	start_cmds
	 nop
	bsr	game_tick
	 nop
	bsr	await_cmds
	 nop
	bsr	copy_istate
	 nop
	bsr	nbgetchar
	 nop
	cmp/pz	r0
	bf	1b
	lds	r11,pr
	rts
	 nop

init_hw:
	mova	9f,r0
1:	mov.l	@r0+,r1
	tst	r1,r1
	bt	1f
	mov.l	@r0+,r2
	bra	1b
	 mov.l	r2,@r1
1:	SETS.L	#curistate,r1
	SETS.L	#previstate,r2
	SETS.L	#0x0000ffff,r3
	mov.l	r3,@r1
	mov.l	r3,@r2
	SETS.L	#0x80808080,r3
	mov.l	r3,@(4,r1)
	mov.l	r3,@(4,r2)
	rts
	 nop
	.align	4
9:	.long	BUS_RESET,	BUS_RESET_VALUE
	.long	BUS_RESET2,	BUS_RESET2_VALUE
	.long	BUS_SPEED,	SPEED_2MBPS|[50000<<SPEED_TIMEOUT_SHIFT]
	.long	BUS_ENABLE,	BUS_ENABLE_VALUE
	.long	0

start_cmds:
	SETS.L	#obuf,r1
	SETS.L	#ocopy,r2
	SETS.L	#192/4,r3
1:	mov.l	@r1+,r0
	mov.l	r0,@r2
	dt	r3
	bf/s	1b
	 add	#4,r2
	add	#-100,r2
	add	#-92,r2
	SETS.L	#192/32,r3
1:	ocbp	@r2
	dt	r3
	bf/s	1b
	 add	#32,r2
	add	#-1,r2
	ocbp	@r2
	SETS.L	#BUS_DMAADDR,r1
	SETS.L	#cmds&DMA_ADDRMASK,r2
	mov.l	r2,@r1
	SETS.L	#BUS_STATE,r3
	SETS.L	#BUS_STATE_GO,r0
	rts
	 mov.l	r0,@r3

await_cmds:
	SETS.L	#BUS_STATE,r3
1:	mov.l	@r3,r0
	tst	#BUS_STATE_RUNNING,r0
	bf	1b
	rts
	 nop

copy_istate:
	SETS.L	#iresp,r9
	; Assume the whole response fits in a single cache line
	; (this depends on both size and alignment)
	ocbi	@r9
	mov.l	@(8,r9),r1
	mov.l	@(12,r9),r2
	SETS.L	#curistate,r8
	mov.l	r1,@r8
	rts
	 mov.l	r2,@(4,r8)

; curistate 0000ffff 80808080 with controller untouched
;
; 0000fff7 80808080	START
; 0000fbff 80808080	X
; 0000fdff 80808080	Y
; 0000fffb 80808080	A
; 0000fffd 80808080	B
; 0000ffbf 80808080	LF
; 0000ff7f 80808080	RT
; 0000ffef 80808080	UP
; 0000ffdf 80808080	DN
; **00ffff 80808080	left trigger
; 00**ffff 80808080	right trigger
; 0000ffff 808080**	joystick X axis (left=00, right=ff)
; 0000ffff 8080**80	joystick Y axis (up=00, down=ff)
game_tick:
	sts.l	pr,@-r15
	SETS.L	#obuf+192,r1
	SETS.L	#192/4,r2
	SETS.L	#0,r0
1:	mov.l	r0,@-r1
	dt	r2
	bf	1b
	SETS.L	#curistate,r9
	mov.l	@(4,r9),r8
	extu.b	r8,r6		; x
	extu.w	r8,r7
	SHXR	#8,r7,r1	; y
	SETS.L	#48,r2
	mul.l	r2,r6
	sts	macl,r6
	SHXR	#8,r6,r1	; x, 0..47
	SHXR	#3,r7		; y, 0..31
	add	#-31,r7
	neg	r7,r7
	mov	r7,r0
	add	r0,r7
	add	r0,r7
	SHLL	#1,r7
	mov	r6,r0
	SHXR	#3,r6
	add	#-5,r6
	sub	r6,r7
	and	#7,r0
	mov	#1,r1
	shld	r0,r1
	SETS.L	#obuf,r2
	add	r2,r7
	mov.b	r1,@r7
	lds.l	@r15+,pr
	rts
	 nop

printhex8:
	mov	#8,r0
printhexN:
	mov.l	r4,@-r15
	mov	r0,r4
	add	#-8,r0
	neg	r0,r0
	SHLL	#2,r0
	shld	r0,r1
	mov.l	r3,@-r15
	mov.l	r2,@-r15
	sts.l	pr,@-r15
	mova	9f,r0
	mov	r0,r3
	mov	r1,r2
1:	mov	r2,r0
	SHLR	#28,r0
	SHLL	#4,r2
	add	r3,r0
	bsr	putchar
	 mov.b	@r0,r1
	dt	r4
	bf	1b
	lds.l	@r15+,pr
	mov.l	@r15+,r2
	mov.l	@r15+,r3
	rts
	 mov.l	@r15+,r4
	.align	4
9:	.ascii	"0123456789abcdef"
	.align	2

putchar2:
	sts.l	pr,@-r15
	bsr	putchar
	 mov.l	r1,@-r15
	mov.l	@r15+,r1
	 lds.l	@r15+,pr
putchar:
	ldc	r14,gbr
1:	mov.w	@(SCFDR2-SCIF_BASE,gbr),r0
	SHXR	#SCFDR2_TX_SHIFT,r0
	and	#SCFDR2_TX_MASK,r0
	cmp/eq	#16,r0
	bt	1b
	mov	r1,r0
	mov.b	r0,@(SCFTDR2-SCIF_BASE,gbr)
1:	mov.w	@(SCFDR2-SCIF_BASE,gbr),r0
	SHXR	#SCFDR2_TX_SHIFT,r0
	tst	#SCFDR2_TX_MASK,r0
	bf	1b
	rts
	 nop

nbgetchar:
	ldc	r14,gbr
	mov.w	@(SCFDR2-SCIF_BASE,gbr),r0
	SHXR	#SCFDR2_RX_SHIFT,r0,r1
	tst	#SCFDR2_RX_MASK,r0
	bt	1f
	mov.b	@(SCFRDR2-SCIF_BASE,gbr),r0
	extu.b	r0,r1
	mov.w	@(SCLSR2-SCIF_BASE,gbr),r0
	mov	#0,r0
	mov.w	r0,@(SCLSR2-SCIF_BASE,gbr)
	rts
	 mov	r1,r0
1:	rts
	 mov	#-1,r0

	SETCONST

.if 0

1c210005

01000000 - func (controller only)
fe060f00 - controller info
		present = 000f06fe
			= 00 1111 0000 0110 1111 1110
			=	analog V 2	no
				analog H 2	no
				analog V	yes
				analog H	yes
				analog L trig	yes
				analog R trig	yes
				> 2		no
				< 2		no
				v 2		no
				^ 2		no
				D		no
				X		yes
				Y		yes
				Z		no
				>		yes
				<		yes
				v		yes
				^		yes
				START		yes
				A		yes
				B		yes
				C		no
00000000 - unused
00000000 - unused
      ff - area code
    00   - connector direction
7244     - product name ("Dreamcast Controller          ")
636d6165
20747361
746e6f43
6c6c6f72
20207265
20202020
20202020
646f7250 - product license ("Produced By or Under License From SEGA ENTERPRISES,LTD.     ")
64656375
20794220
5520726f
7265646e
63694c20
65736e65
6f724620
4553206d
45204147
5245544e
53495250
4c2c5345
202e4454
20202020
    01ae - standby power (430)
01f4     - max power (500)
4553206d - wtf?
4553206d
4553206d


1c010005

0e000000 - func (clock, LCD, memory card)
403f7e7e - clock info
00100500 - LCD info
00410f00 - memory card info
      ff - area code
    00   - connector direction
6956     - product name
6c617573
6d654d20
2079726f
20202020
20202020
20202020
20202020
646f7250 - product license
64656375
20794220
5520726f
7265646e
63694c20
65736e65
6f724620
4553206d
45204147
5245544e
53495250
4c2c5345
202e4454
20202020
    007c - standby power (124)
0082     - max power (130)
4553206d - wtf?
4553206d
4553206d

03210008
01000000
0000ffff
80808080

.endif