[[ Start with an empty string. ]]
""

[[ If the message is current for its folder, mark it with a >; if unseen,
   mark it with N.  Previous and next messages get - and + markings, akin
   to the > to mark the current message. ]]
m?#c ??
  ">"
?| m?#p ?+
  "-"
?| m?#n ?+
  "+"
?|
  " "
?. $+
mf "unseen" mn qm ?? "N" ?| " " ?. $+

[[ If in the current folder, use three-column numbers;
   otherwise, folder:number. ]]
m?cf ?? mn 3 ' ' $<<i ?| mf ":" $+ mn $<i $+ ?. $+

[[ Space between message number and date. ]]
" " $+

[[ If date is in the last 24 hours, use hh:mm
   Else if within the last six months, use mmmdd
   Else if within last ten years, use yymmm
   Else use yyyy
   But if the date is missing or invalid, use (???). ]]
hs(Date) hdp s+ 0 < ??
  s- "(???)"
?|
  hdc so -
  s+ 86400 < ??
    s- s+ hdh 2 '0' $<<i ":" $+ sx hdm 2 '0' $<<i $+
  ?| s+ 15778476 < ?+
    s- s+ hdM hd$M sx hdD 2 '0' $<<i $+
  ?| s+ 315569520 < ?+
    s- s+ hdY 100 % 2 '0' $<<i sx hdM hd$M $+
  ?|
    s- hdY 4 '0' $<<i " " sx $+
  ?.
?.
$+

[[ Sender's address.  If multiple addresses on the From: line, it's
   almost certainly a spam, so just put (MULTIPLE). ]]
hs(From) s+ ha# 1 > ??
  s- "(MULTIPLE)"
?|
  haa
?.
" " sx $+ $+

[[ Add the Subject, in quotes. ]]
" \"" hs(Subject) "\"" $+ $+ $+

[[ Truncate to @width, less one character to avoid rightmost column. ]]
0 @width 1 - $_