@prog tess-look.muf
1 999 d
1 i
: say me @ swap notify ;
: obj-visible? "_tess" prop-exists? ;
: exit-visible? dup "dark" prop-exists? swap "d" flag? or not ;
: say-or-run dup "@" 1 strncmp if say else 1 strcut swap pop atoi dbref "" swap call then ;
: cat-or-say (sofar str maxlen -- sofar)
	over strlen 4 pick strlen + < if
		swap say
	else
		strcat
	then
;
: exit-name name dup ";" instr dup if 1 - strcut pop else pop then ;
: look-room
	me @ loc @ owner dbcmp if
		loc @ dup name " [#" strcat over int intostr strcat
		swap flagstr strcat "]" strcat say
	else
		loc @ name say
	then
	"You see around you:" say
	"" loc @ contents begin dup while
		dup obj-visible? if
			swap over name "  " swap "." strcat strcat
			78 cat-or-say swap
		then
		next
	loop
	pop
	dup not if pop "  Nothing special." then say
	"Exits:" say
	"" loc @ exits begin dup while
		dup exit-visible? if
			swap over exit-name "  " swap "." strcat strcat
			78 cat-or-say swap
		then
		next
	loop
	pop
	dup not if pop "  none." then say
;
: look-thing dup trigger ! desc say-or-run ;
: main
	dup not if pop look-room exit then
	match
	dup thing? if look-thing exit then
	pop "That object is not here." say
;
.
c
q