@prog quota.muf
1 9999 d
1 i
$def quota-prop "@building-quota"
: say me @ swap notify ;
: name-verb (player verb-3p verb-2p -- s)
	3 pick me @ dbcmp if
		-rot pop pop "You " swap strcat
	else
		pop swap name " " rot 3 "" rimplode
	then
;
: not-subject
	"is" "are" name-verb " not subject to building quotas." strcat say
;
: current-values (max-quota cur-owned-count -- s s s s s)
	" (" swap intostr " owned, quota " 4 rotate intostr ")."
;
: do-quota-report (player quota-holder-dbref -- )
	quota-prop getpropstr atoi
	( player max-quota )
	over numowned
	( player max-quota cur-number )
	over over > if
		rot "has" "have" name-verb " " 4 pick 4 pick -
		dup 1 = if "dbref" else "dbrefs" then
		swap intostr swap " " swap " of quota available"
		8 -2 roll current-values
		11
	else over over < eif
		rot "is" "are" name-verb " already over quota"
		4 -2 roll current-values
		7
	else
		pop swap "is" "are" name-verb " exactly at quota, "
		rot intostr " dbrefs." 4
	then
	"" rimplode say
;
: main
	me @ true-wizard? not if pop "" then
	dup if "*" swap strcat match else pop me @ then
	dup not if pop "Not a player!" say exit then
	dup true-wizard? if not-subject exit then
	dup quota-prop prop-exists? if dup do-quota-report exit then
	#0 quota-prop prop-exists? if #0 do-quota-report exit then
	not-subject
;
.
c
q