@prog multiroom-hear.muf
1 999 d
1 i
: notify-contents (room msg)
	trigger @ location
	( room msg from )
	"_multiroom-prefix-" 4 pick int intostr strcat over over prop-exists?
	if
		getpropstr " " strcat
	else
		pop "_multiroom-prefix" over over prop-exists?
		if
			getpropstr " " strcat
		else
			pop pop ""
		then
	then
	swap strcat
	swap contents
	begin dup while
		dup 3 pick notify
		next
	loop
	pop pop
;
: main
	( msg )
	trigger @ location dup room? over owner wizard? or not if pop exit then
	dup "_multiroom" getpropstr "," explode
	( msg room rs1 ... rsN N )
	dup 3 + dup 1 +
	( msg room rs1 ... rsN N N+3 N+4 )
	rotate swap rotate
	( rs1 ... rsN N msg room )
	1 4 rotate 1 for pop
		rot atoi dbref
		over over dbcmp over me @ location dbcmp or if
			pop
		else
			0 swap
			over not if dup player? if
				3 pick owner
				over over dbcmp not swap wizard? or if
					swap pop 1 swap
					4 pick notify #-1
				then
			then then
			over not if dup room? if
				3 pick owner over owner
				over dbcmp swap wizard? or if
					swap pop 1 swap
					4 pick notify-contents #-1
				then
			then then
			pop pop
		then
	loop
	pop pop
;
.
c
q